CSE 341 -- Smalltalk Intro

Background

The Learning Research Group at Xerox Palo Alto Research Center (PARC) developed Smalltalk as a language for the Dynabook, during the 70s and early 80s. The Dynabook was a yet-to-be-developed "laptop of the future." Alan Kay, Dan Ingalls, Adele Goldberg were key players in the development of Smalltalk. They selected simulation as the metaphor for programming the Dynabook. Smalltalk was influenced by Lisp, Simula, Ivan Sutherland's Sketchpad.

Characteristics of Smalltalk-72:

interpreted
extensible syntax: fred move up x inches
more object-oriented than Simula -- even integers are objects
'class' is an object (but a rather special one). No subclassing

Characteristics of Smalltalk-80:

everything is an object, even classes, blocks (closures), activation records, etc.
classes can have subclasses
not statically typed
rich programming environment
definitely no longer a programming language for kids!

Smalltalk-80 is now a commercial product (ParcPlace Systems, Digitalk, Object Technology International), and a hot item on Wall Street and the MIS world

Smalltalk influenced the development of other object-oriented languages, such as C++, Objective C, CLOS, and our own Cecil and Kaleidoscope languages, as well as others.

Language Overview

We'll now give a quick overview of the language, via a few small examples. Basic concepts:

objects
instances
classes
messages and methods

Syntax:

unary messages, eg.

Date today
Time now hours
Array new
someCollection copy

keyword messages, eg.

Array new: 10  
someArray at: 1 put: 54
anArray at: 1

binary messages (look like binary operators), eg.
```
5 * 9
3 + 2 * 5
```

Precedence:

High to low: unary, binary, keyword, left-to-right within same kind,
Use parentheses to override
Question: What is the value of 3 + 2 * 5 ?

Note that we will very frequently be composing messages -- for example

Time now hours + 1

First sends the message now to the class Time, which returns the current time (an instance of Time). We then send this object the message hours, which returns an integer. Then we send the message + with the argument 1 to this integer, returning another integer (which will be the current hour plus 1).

Example 1: Stack

Object subclass: 'Stack'
    instanceVariables: 'store top'


push: item
   top := top+1.
   store at: top put: item


pop 
   | item | 
   item := store at: top.
   top := top-1.
   ^ item

setsize: n
   store := Array new: n.
   top := 0.

Adding error checking and growing:

push: item
   | oldStore |
   top := top+1.
   top > store size ifTrue: 
      "store is about to overflow.  make a new array twice as big, and
       copy the old values into it"
      [oldStore := store.
       store    := Array new: 2 * oldStore size.
       1 to: oldStore size do:
          [:k | store at: k put: (oldStore at: k)]].
   store at: top put: item


pop | item | 
   self isEmpty ifTrue: [self error: 'trying to pop an empty stack'].
   item := store at: top.
   top := top-1.
   ^ item

isEmpty
   ^ top=0

dugan@cs.washington.edu (Last Update: )