/* candyGrab.pde
   Written by Justin Hsia
   
   CandyGrab game (nim variant) implemented in Processing.
   Only a few simple player types ("agents") implemented.
   
   Plays N games and reports the winning statistics based
   on pieces remaining and move taken for the player who
   goes first.
*/

// choose whether to play 1 game at a time by clicking (true)
// or play N games all at once (false)
boolean step = false;

int numPieces = 10, N = 100000;
int[][] moveWon  = new int[2][numPieces];  // 2D array to track times won by playing this move
int[][] movePlay = new int[2][numPieces];  // 2D array to track times played this move


void setup() {
  size(1000,300);
  background(255);
  textAlign(CENTER);
  rectMode(CENTER);
  // initialize arrays
  for(int i=0; i<numPieces; i=i+1) {
    moveWon[0][i] = 0;
    moveWon[1][i] = 0;
    movePlay[0][i] = 0;
    movePlay[1][i] = 0;
  }
}

void draw() {
  if(step) {
    // play single game of Candy Grab
    candyGrab(numPieces,0);
  } else {
    // play N games of Candy Grab
    for(int i=0; i<N; i=i+1) {
      candyGrab(numPieces,0);
    }
  }
  background(255);
  printStats();
  noLoop();
}


// detect mouse clicks to play one additional game if step == true
void mousePressed() {
  if(step) {
    loop();
  }
}


// recursive implementation of Candy Grab game
int candyGrab(int numPieces, int player) {
  int move, result;
  
  // check for end of game (BASE CASE)
  if(numPieces <= 0) {
    return player;  // returns 0 if Player 1 won, 1 if Player 0 won
  }
  
  // determine the player's move based on chosen strategy
  if(player == 0) {
    move = agentR();
  } else {
    move = agent7(numPieces);    // CHANGE THIS LINE to switch opponent strategies
  }
  result = candyGrab(numPieces-move,1-player);  // RECURSE
  
  // only update stats for Player 0
  if(player == 0) {
    moveWon[move-1][numPieces-1] += result;
    movePlay[move-1][numPieces-1] += 1;
  }
  
  return result;
}


// print final statistics from playing N games
void printStats() {
  int w = 80, o = 120;      // box width (w) and horizontal offset (o) from the left 
  int h1 = 140, h2 = 220;   // y-coordinate for text in 1st (h1) and 2nd (h2) row
  fill(0);
  textSize(40);
  text("Play 1:",80,h1);
  text("Play 2:",80,h2);
  for(int i=0; i<numPieces; i=i+1) {
    noFill();
    rect(o+w*(i+1),h1-15,w,60);         // upper box
    rect(o+w*(i+1),h2-15,w,60);         // lower box
    fill(0);
    text(numPieces-i,o+w*(i+1),h1-60);  // numPieces header row
    if(movePlay[0][numPieces-1-i] == 0) {
      text("n/a",o+w*(i+1),h1);
    } else {
      text((int)(100*moveWon[0][numPieces-1-i]/movePlay[0][numPieces-1-i]),o+w*(i+1),h1);
    }
    if(movePlay[1][numPieces-1-i] == 0) {
      text("n/a",o+w*(i+1),h2);
    } else {
      text((int)(100*moveWon[1][numPieces-1-i]/movePlay[1][numPieces-1-i]),o+w*(i+1),h2);
    }
  }
}


/*************
| THE AGENTS |
*************/

// always takes 1 piece
int agent1() {
  return 1;
}

// always takes 2 pieces
int agent2() {
  return 2;
}

// plays winning strategy (needs to know how many pieces are remaining)
int agent7(int p) {
  if(p%3 == 2) {
    return 2;
  } else {
    return 1;
  }
}

// returns random move
int agentR() {
  return (int)random(1,3);
}